import QtQuick 2.15
import QtQuick.Controls 2.15

Drawer {
    property alias logo: logoImage.source
    property alias appName: appNameLabel.text
    property alias model: menuRepeater.model
    property alias additional: additionalLabel.sourceComponent

    signal actionSelected(var action)

    width: parent.width * 0.66
    height: parent.height

    Column {
        anchors.fill: parent

        Row {
            width: parent.width
            height: 100

            Image {
                id: logoImage

                anchors.top: parent.top
                anchors.bottom: parent.bottom
                anchors.margins: 10
            }

            Column {
                anchors.verticalCenter: parent.verticalCenter

                Label {
                    id: appNameLabel

                    font.pointSize: 20
                }

                Loader {
                    id: additionalLabel
                }
            }
        }

        Repeater {
            id: menuRepeater

            delegate: ItemDelegate {
                width: parent.width

                text: model.title
                onClicked: actionSelected(model.action)
            }
        }
    }
}